%# BEGIN BPS TAGGED BLOCK {{{
%#
%# COPYRIGHT:
%#
%# This software is Copyright (c) 1996-2026 Best Practical Solutions, LLC
%#                                          <sales@bestpractical.com>
%#
%# (Except where explicitly superseded by other copyright notices)
%#
%#
%# LICENSE:
%#
%# This work is made available to you under the terms of Version 2 of
%# the GNU General Public License. A copy of that license should have
%# been provided with this software, but in any event can be snarfed
%# from www.gnu.org.
%#
%# This work is distributed in the hope that it will be useful, but
%# WITHOUT ANY WARRANTY; without even the implied warranty of
%# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
%# General Public License for more details.
%#
%# You should have received a copy of the GNU General Public License
%# along with this program; if not, write to the Free Software
%# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
%# 02110-1301 or visit their web page on the internet at
%# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
%#
%#
%# CONTRIBUTION SUBMISSION POLICY:
%#
%# (The following paragraph is not intended to limit the rights granted
%# to you to modify and distribute this software under the terms of
%# the GNU General Public License and is only of importance to you if
%# you choose to contribute your changes and enhancements to the
%# community by submitting them to Best Practical Solutions, LLC.)
%#
%# By intentionally submitting any modifications, corrections or
%# derivatives to this work, or any other work intended for use with
%# Request Tracker, to Best Practical Solutions, LLC, you confirm that
%# you are the copyright holder for those contributions and you grant
%# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
%# royalty-free, perpetual, license to use, copy, create derivative
%# works based on those contributions, and sublicense and distribute
%# those contributions and any derivatives thereof.
%#
%# END BPS TAGGED BLOCK }}}
<%ARGS>
%Table => ()
$Query => 'id > 0'
$Class => 'RT::Tickets'
</%ARGS>
<%INIT>

my %base_query = map { $_ => $ARGS{$_} }
    grep { defined $ARGS{$_} and length $ARGS{$_} } @RT::Interface::Web::SHORTENER_SEARCH_FIELDS;

my $interp = $m->interp;
my $eh  = sub { $interp->apply_escapes( @_, 'h' ) };
my $eu  = sub { $interp->apply_escapes( @_, 'u' ) };

$m->out('<div class="table-responsive">');
$m->out('<table class="table ' . RT->Config->Get('TableAccent') . ' table-bordered collection-as-table chart">'. "\n");
foreach my $section (qw(thead tbody tfoot)) {
    next unless $Table{ $section } && @{ $Table{ $section } };

    $m->out("<$section>\n");
    foreach my $row ( @{ $Table{ $section } } ) {
        $m->out('  <tr>');

        foreach my $cell ( @{ $row->{'cells'} } ) {
            my $tag = $cell->{'type'} eq 'value'? 'td' : 'th';
            $m->out("<$tag");

            if ( $tag eq 'th' ) {
                if ( $cell->{'type'} eq 'head' ) {
                    $m->out(' scope="col" ');
                }
                else {
                    $m->out(' scope="row" ');
                }
            }

            my @class = ('collection-as-table');
            push @class, ($cell->{'type'}) unless $cell->{'type'} eq 'head';
            $m->out(' class="'. $eh->( join ' ', @class ) .'"');

            foreach my $dir ( grep $cell->{$_}, qw(rowspan colspan) ) {
                my $value = int $cell->{ $dir };
                $m->out(qq{ $dir="$value"});
            }

            $m->out('>');
            if ( defined $cell->{'value'} ) {
                if ( my $q = $cell->{'query'} ) {
                    $m->out(
                        '<a href="'. $eh->(RT->Config->Get('WebPath')) .'/Search/Results.html?'
                        . $eh->(
                            QueryString(
                                ShortenSearchQuery(
                                    %base_query,
                                    Query => $Query =~ /^\s*\(.*\) AND \(?\Q$q\E\)?$/
                                    ? $Query
                                    : join( ' AND ', map { /^\s*\(.*\)$/ ? $_ : "($_)" } $Query, $q ),
                                )
                            )
                        )
                        . '" target="_blank">'
                    );
                    $m->out( $cell->{value} );
                    $m->out('</a>');
                }
                else {
                    $m->out( $cell->{value} );
                }
            }
            else {
                $m->out('&nbsp;');
            }
            $m->out("</$tag>");
        }
        $m->out("</tr>\n");
    }
    $m->out("</$section>\n\n");
}
$m->out("</table>");
$m->out("</div>");
</%INIT>
